Scheme - 手続きによる抽象の構築(高階手続きによる抽象(引数としての手続き(accumulator、再帰的プロセス、反復的プロセス)))

計算機プログラムの構造と解釈[第2版]
原著

開発環境

• OS X El Capitan - Apple (OS)
• Emacs(Text Editor)
• Scheme (プログラミング言語)
• kscheme (ksi)(github) (処理系)

計算機プログラムの構造と解釈[第2版](ハロルド エイブルソン (著)、ジュリー サスマン (著)、ジェラルド・ジェイ サスマン (著)、Harold Abelson (原著)、Julie Sussman (原著)、Gerald Jay Sussman (原著)、和田 英一 (翻訳)、翔泳社、原著: Structure and Interpretation of Computer Programs (MIT Electrical Engineering and Computer Science)(SICP))の第1章(手続きによる抽象の構築)、1.3(高階手続きによる抽象)、1.3.1(引数としての手続き)、問題1.32-a、b.を取り組んでみる。

その他参考書籍

• Instructor's Manual to Accompany Structure & Interpretation of Computer Programs

問題1.32-a、b.

コード(Emacs)

(begin
  (load "procedures.scm")
  (newline)

  (define (p x) (display x) (newline))
  ;; 再帰的プロセス
  (define (accumulate1 combiner null-value term a next b)
    (if (> a b)
        null-value
        (combiner (term a)
                  (accumulate1 combiner null-value term (next a) next b))))
  ;; 反復的プロセス
  (define (accumulate2 combiner null-value term a next b)
    (define (iter a result)
      (if (> a b)
          result
          (iter (next a) (combiner (term a) result))))
    (iter a null-value))

  (define (sum1 term a next b) (accumulate1 + 0 term a next b))
  (define (sum2 term a next b) (accumulate2 + 0 term a next b))
  (define (product1 term a next b) (accumulate1 * 1 term a next b))
  (define (product2 term a next b) (accumulate2 * 1 term a next b))

  (define (id x) x)
  (define (inc x) (+ x 1))
  
  (p (sum1 id 1 inc 10))
  (p (sum2 id 1 inc 10))  
  (p (product1 id 1 inc 10))
  (p (product2 id 1 inc 10))            
  'done)

入出力結果(Terminal(kscheme), REPL(Read, Eval, Print, Loop))

$ ksi < sample32.scm
ksi> 
55
55
3628800
3628800
=> done
ksi> $